simulated function bool RotatingProcess(float dt, optional bool Align)
{
   local float NewChasYaw, ChasYaw, DeltaYaw;
   local Actor AITarget;

   ChasYaw = Normalize(RelChasRot).Yaw;
   if ((Align != true) || (bDriving != false))
    {
     if (PlayerController(Controller) != none)
      {
       NewChasYaw = Normalize(Rotation).Yaw - Normalize(Controller.Rotation).Yaw;
       if ((abs(NewChasYaw - ChasYaw) < 3000) || (abs(NewChasYaw - ChasYaw) > 62536))
        ShowLock = true;
       else
        ShowLock = false;
      }
     else if (Bot(Controller) != none)
      {
       AITarget = none;
       if (Bot(Controller).Enemy != none)
        AITarget = Bot(Controller).Enemy;
       else if (Bot(Controller).Focus != none)
        AITarget = Bot(Controller).Focus;
       if (AITarget != none)
        NewChasYaw = Normalize(Rotation).Yaw - rotator(AITarget.Location - Location).Yaw;
       else
        NewChasYaw = Normalize(Rotation).Yaw -  Normalize(Controller.GetViewRotation()).Yaw;
      }
    }
   else
    {
     NewChasYaw = 0; // align when parking
     if ( abs(NewChasYaw - ChasYaw) < 0.1 )
       return true;
    }
   if (abs(NewChasYaw - ChasYaw) < 32768)
    DeltaYaw = (NewChasYaw - ChasYaw);
   else
    {
     if (NewChasYaw > 0)
      DeltaYaw = (NewChasYaw - ChasYaw - 65536);
     else
      DeltaYaw = (NewChasYaw - ChasYaw + 65536);
    }

    if (DeltaYaw > 0)
     RelChasRot.Yaw = ChasYaw + Min(Rotating_Speed, abs(DeltaYaw)*5)*dt;
    else if (DeltaYaw < 0)
     RelChasRot.Yaw = ChasYaw - Min(Rotating_Speed, abs(DeltaYaw)*5)*dt;

   if (abs(DeltaYaw) < Rotating_Speed*dt)
    SoundVolume = 0;
   else
    SoundVolume = 128;

   SetBoneRotation('chassis_bone', RelChasRot);
   return false;
}