class PROJ_IspolinAP extends DKProjectile;

var vector Dir;

var FX_FireEffect_Ispolin Fire;
var FX_Tracer_IspolinAP Tracer;

simulated function PostBeginPlay()
{
Fire = Spawn(class'FX_FireEffect_Ispolin',self,,Location);
Tracer = Spawn(class'FX_Tracer_IspolinAP',self,,Location);

Super.PostBeginPlay();
}

function BlowUp(vector HitLocation)
{
HurtRadius(Damage, DamageRadius, MyDamageType, MomentumTransfer, HitLocation );
MakeNoise(1.0);
}

simulated event Landed( vector HitNormal )
{
HitWall(HitNormal, None);
}

simulated event HitWall(vector HitNormal, actor Wall)
{
local Vector VNorm;
local Rotator NewRotation;

Vnorm = (Velocity dot HitNormal) * HitNormal;
NewRotation = rotator(-VNorm + (Velocity - VNorm));

Spawn(class'FX_Tracer_IspolinAP',,,Location, NewRotation);

Explode(Location, HitNormal);
}

simulated function Explode(vector HitLocation, vector HitNormal)
{
Destroy();
}

simulated function Destroyed()
{
Tracer.Destroy();
Super.Destroyed();
}

defaultproperties
{
EhoFireSound=SoundGroup'DKoppIISound.Hit.EhoC'
EhoFireSoundVolume=2.000000
EhoFireSoundRadius=100000.000000

EhoExpSound=SoundGroup'DKoppIISound.Hit.EhoExpA'
EhoExpSoundVolume=2.000000
EhoExpSoundRadius=100000.000000

ImpactManager=Class'DKoppIIVehicles.IM_Ammo76AP'
SplashManager=Class'BallisticProMainOff.IM_ProjWater'

ShakeRadius=176.000000
MotionBlurRadius=176.000000
MotionBlurFactor=10.000000

Speed=20000.000000
MaxSpeed=20000.000000

Damage=760.000000
DamageRadius=176.000000
MomentumTransfer=10000.000000

MyDamageType=Class'DKoppIIVehicles.DT_AP'

StaticMesh=None

DrawScale=0.000000

ForceType=FT_Constant
ForceRadius=100.000000
ForceScale=5.000000
}

class DKProjectile extends BallisticProjectile;

var() Sound             EhoFireSound;
var() ESoundSlot        EhoFireSoundSlot;
var() float             EhoFireSoundVolume;
var() bool              EhoFireSoundNoOverride;
var() float             EhoFireSoundRadius;
var() float             EhoFireSoundPitch;
var() bool              EhoFireSoundAttenuate;

var() Sound             EhoExpSound;
var() ESoundSlot        EhoExpSoundSlot;
var() float             EhoExpSoundVolume;
var() bool              EhoExpSoundNoOverride;
var() float             EhoExpSoundRadius;
var() float             EhoExpSoundPitch;
var() bool              EhoExpSoundAttenuate;

simulated function PostBeginPlay()
{
PlaySound(EhoFireSound, EhoFireSoundSlot, EhoFireSoundVolume, EhoFireSoundNoOverride, EhoFireSoundRadius, EhoFireSoundPitch, EhoFireSoundAttenuate);

Super.PostBeginPlay();
}

function float SurfaceScale (int Surf, out byte bHard)
{
switch (Surf)
{
Case 0:/*EST_Default*/                return 1;
Case 1:/*EST_Rock*/ return 1;
Case 2:/*EST_Dirt*/ return 1;
Case 3:/*EST_Metal*/ return 1;
Case 4:/*EST_Wood*/ return 1;
Case 5:/*EST_Plant*/ return 1;
Case 6:/*EST_Flesh*/ return 1;
Case 7:/*EST_Ice*/ return 1;
Case 8:/*EST_Snow*/ return 1;
Case 9:/*EST_Water*/ return 1;
Case 10:/*EST_Glass*/ return 1;
default: return 1;
}
}

simulated function ProcessTouch (Actor Other, vector HitLocation)
{
PlaySound(EhoExpSound, EhoExpSoundSlot, EhoExpSoundVolume, EhoExpSoundNoOverride, EhoExpSoundRadius, EhoExpSoundPitch, EhoExpSoundAttenuate);

if (Other == None || (!bCanHitOwner && (Other == Instigator || Other == Owner || ( vehicle(Instigator)!=None&&Other==Vehicle(Instigator).Driver ) )))
return;

if (Role == ROLE_Authority) // Do damage for direct hits
DoDamage(Other, HitLocation);

HitActor = Other;
Explode(HitLocation, vect(0,0,1));
}

defaultproperties
{
bCheckHitSurface=True
bAlwaysRelevant=True
bDynamicLight=True
bFullVolume=True

LifeSpan=20.000000

NetUpdateFrequency=1.000000
NetPriority=3.000000

LightType=LT_Steady
LightEffect=LE_QuadraticNonIncidence
LightHue=28
LightSaturation=127
LightBrightness=100.000000
LightRadius=1.000000

ForceType=FT_Constant
ForceRadius=100.000000
ForceScale=5.000000
}

class BallisticProjectile extends Projectile
abstract
config(BallisticProMainOff);

var() class<BCImpactManager>ImpactManager; // Impact manager to spawn on final hit
var() class<BCImpactManager>PenetrateManager; // Impact manager to spawn when going through actors
var() bool bCheckHitSurface; // Check impact surfacetype on explode for surface dependant ImpactManagers
var() bool bPenetrate; // Will go through enemies
var() bool bRandomStartRotaion; // Set random roll on startup
var() float AccelSpeed; // Acceleration speed
var() float StartDelay; // Used to delay projectile's entry into the world
var() class<Actor> TrailClass; // Actor to use for trail
var  Actor Trail; // The trail Actor
var() Vector TrailOffset; // Offset from location at which to spawn trail
var() class<DamageType> MyRadiusDamageType; // DamageType to use for splash damage
var   actor HitActor; // Actor that got hit directly
var   bool bCanHitOwner; // Bounced or turned around or something so it can hit owner
var   bool bExploded; // Already Blown up. Used by troublesome rocekts that keep going off on clients
var() bool bTearOnExplode; // If !bNetTemporary, tear this projectile off when it explodes
var() float NetTrappedDelay; // How long to remain in nettrapped state before being destroyed
var() bool bUsePositionalDamage; // Enable damage variation depending on hitlocation

var() float DamageHead; // Damage for headshots
var() float DamageLimb; // Damage for limb shots
var() globalconfig float DamageModHead, DamageModLimb; //Configurable damage modifiers for base damage
var() class<DamageType> DamageTypeHead; // Damagetype for headshots
var() class<DamageType> DamageTypeLimb; // Damagetype for limbshots

var() class<BCImpactManager>SplashManager; // Impact manager to spawn for splashes
var() float ShakeRadius; // Shake the view of players withing this radius when Exploding
var() bool bWarnEnemy; // Warn enemies that it's coming for em
var() float MotionBlurRadius;
var() float MotionBlurFactor;
var() float MotionBlurTime;

var() bool bCoverPenetrator;
// camera shakes //
var() vector ShakeRotMag;           // how far to rot view
var() vector ShakeRotRate;          // how fast to rot view
var() float  ShakeRotTime;          // how much time to rot the instigator's view
var() vector ShakeOffsetMag;        // max view offset vertically
var() vector ShakeOffsetRate;       // how fast to offset view vertically
var() float  ShakeOffsetTime;       // how much time to offset view

var Vector TearOffHitNormal;

replication
{
reliable if (bTearOff && Role == ROLE_Authority)
TearOffHitNormal;
}

simulated event TornOff()
{
Explode(Location, TearOffHitNormal);
}

//LinkGun version
simulated function PostBeginPlay()
{
    local Rotator R;
    
    Super(Projectile).PostBeginPlay();

Velocity = Vector(Rotation);
Velocity *= Speed;

if(bRandomStartRotaion) //lol
{
R = Rotation;
R.Roll = Rand(65536);
SetRotation®;
}
}

//Modified LinkGun
simulated function PostNetBeginPlay()
{
local PlayerController PC;

    Acceleration = Normal(Velocity) * AccelSpeed;

if (StartDelay > 0)
{
if(Role == ROLE_Authority || bNetOwner || bAlwaysRelevant)
{
SetPhysics(PHYS_None);
bHidden=true;
SetTimer(StartDelay, false);
bDynamicLight=false;
return;
}

else StartDelay = 0;
}

InitProjectile();

if (Level.NetMode == NM_DedicatedServer)
return;
if ( Level.bDropDetail || Level.DetailMode == DM_Low )
{
bDynamicLight = false;
LightType = LT_None;
}
else
{
PC = Level.GetLocalPlayerController();
if ( (PC == None) || (Instigator == None) || (PC != Instigator.Controller) )
{
bDynamicLight = false;
LightType = LT_None;
}
}
}

simulated function Destroyed()
{
if (Trail != None)
{
if (Emitter(Trail) != None)
Emitter(Trail).Kill();
else
Trail.Destroy();
}
Super.Destroyed();
}

simulated function InitEffects ()
{
local Vector X,Y,Z;

if (Level.NetMode != NM_DedicatedServer)
{
if (TrailClass != None && Trail == None)
{
GetAxes(Rotation,X,Y,Z);
Trail = Spawn(TrailClass, self,, Location + X*TrailOffset.X + Y*TrailOffset.Y + Z*TrailOffset.Z, Rotation);
if (Emitter(Trail) != None)
class'BallisticEmitter'.static.ScaleEmitter(Emitter(Trail), DrawScale);
if (Trail != None)
Trail.SetBase (self);
}
}
}

// Initialize projectile stuff. This will be delayed by StartDelay
simulated function InitProjectile ()
{
InitEffects();
}

// When start delay ends, set all the properties that make it visible
simulated function Timer()
{
if (StartDelay > 0)
{
StartDelay = 0;
SetPhysics(default.Physics);
bDynamicLight=default.bDynamicLight;
bHidden=false;
InitProjectile();
return;
}
}
// Returns false so that physics volumes don't play any sounds
simulated function bool CanSplash()
{
return false;
// return bReadyToSplash;
}

simulated function PhysicsVolumeChange( PhysicsVolume NewVolume )
{
local Actor A;
local vector HitLoc, HitNorm, Start, End;
if (SplashManager != None && bReadyToSplash && NewVolume.bWaterVolume)
{
Start = Location - Velocity*(Level.TimeSeconds - LastRenderTime);
End = Location;
bTraceWater=true;
A = Trace(HitLoc, HitNorm, End, Start, true);
bTraceWater=false;
if (A != NewVolume)
HitLoc = Start;
SplashManager.static.StartSpawn(HitLoc, Normal(-Velocity), 9, Instigator);
}
}

simulated function CheckSurface(vector StartLocation, vector StartNormal, out int Surf, optional out Actor Wall)
{
local Vector HitLoc, HitNorm;
local Material HitMaterial;

Wall = Trace(HitLoc, HitNorm, StartLocation - StartNormal*4, StartLocation + StartNormal*4, false,,HitMaterial);
if (Wall == None)
return;

if (Vehicle(Wall) != None)
Surf = 3;
else if (HitMaterial == None)
Surf = int(Wall.SurfaceType);
else
Surf = int(HitMaterial.SurfaceType);
}

simulated function ShakeView(vector HitLocation)
{
local PlayerController PC;
local float Dist, ScaleFactor;

PC = level.GetLocalPlayerController();
if ( PC != None && PC.ViewTarget != None/* && PC.ViewTarget.Base != None */)
{
Dist = VSize(HitLocation - PC.ViewTarget.Location);
if (Dist < MotionBlurRadius)
{
ScaleFactor = (MotionBlurRadius - Dist) / MotionBlurRadius;
class'BC_MotionBlurActor'.static.DoMotionBlur(PC, MotionBlurFactor * ScaleFactor, MotionBlurTime * ScaleFactor);
}
if (Dist < ShakeRadius)
{
if (Dist < ShakeRadius/3)
ScaleFactor = 1.0;
else
ScaleFactor = (ShakeRadius - Dist) / ShakeRadius;
PC.ShakeView(ShakeRotMag*ScaleFactor, ShakeRotRate, ShakeRotTime, ShakeOffsetMag*ScaleFactor, ShakeOffsetRate, ShakeOffsetTime);
}
}
}

// Returns the amount by which MaxWallSize should be scaled for each surface type. Override in subclasses to change...
function float SurfaceScale (int Surf, out byte bHard) //hurp durp you can't have an out bool.
{
switch (Surf)
{
Case 0:/*EST_Default*/ bHard = 1; return 0.5;
Case 1:/*EST_Rock*/ bHard = 1; return 0.5;
Case 2:/*EST_Dirt*/ return 0.35;
Case 3:/*EST_Metal*/ bHard = 1; return 0.25;
Case 4:/*EST_Wood*/ return 0.55;
Case 5:/*EST_Plant*/ return 0.5;
Case 6:/*EST_Flesh*/ return 1;
Case 7:/*EST_Ice*/ bHard=1;return 0.75;
Case 8:/*EST_Snow*/ return 1;
Case 9:/*EST_Water*/ return 1;
Case 10:/*EST_Glass*/ return 1;
default: bHard = 1; return 0.5;
}
}

// Spawn impact effects, run BlowUp() and then die.
simulated function Explode(vector HitLocation, vector HitNormal)
{
local int Surf;

if (bExploded)
return;

if (ShakeRadius > 0 || MotionBlurRadius > 0)
ShakeView(HitLocation);

    if (ImpactManager != None && level.NetMode != NM_DedicatedServer)
{
if (bCheckHitSurface)
CheckSurface(HitLocation, HitNormal, Surf);
if (Instigator == None)
ImpactManager.static.StartSpawn(HitLocation, HitNormal, Surf, Level.GetLocalPlayerController()/*.Pawn*/);
else
ImpactManager.static.StartSpawn(HitLocation, HitNormal, Surf, Instigator);
}

BlowUp(HitLocation);
bExploded = True;

if (!bNetTemporary && bTearOnExplode && (Level.NetMode == NM_DedicatedServer || Level.NetMode == NM_ListenServer))
{
Velocity = vect(0,0,0);
SetCollision(false,false,false);
TearOffHitNormal = HitNormal;
bTearOff = true;
GoToState('NetTrapped');
}

else 
Destroy();

}

function HideProjectile()
{
SetPhysics(PHYS_None);
bAlwaysRelevant=True; //required to force bTearOff update
bHidden=True;
SetTimer(StartDelay, false);
bDynamicLight=false;
AmbientSound=None;
}

state NetTrapped
{
function BeginState()
{
HideProjectile();
SetTimer(NetTrappedDelay, false);
}
event Timer ()
{
Destroy();
}
simulated function Explode(vector HitLocation, vector HitNormal)
{

}
}

// Do radius damage;
function BlowUp(vector HitLocation)
{
if (Role < ROLE_Authority)
return;
if (DamageRadius > 0)
TargetedHurtRadius(Damage, DamageRadius, MyRadiusDamageType, MomentumTransfer, HitLocation, HitActor);
MakeNoise(1.0);
}

// Hit something interesting
simulated function ProcessTouch (Actor Other, vector HitLocation)
{
    local Vector X;

if (Other == None || (!bCanHitOwner && (Other == Instigator || Other == Owner)))
return;

// Do damage for direct hits
if (Role == ROLE_Authority && HitActor != Other)
DoDamage(Other, HitLocation);

if (CanPenetrate(Other) && Other != HitActor)
{ // Projectile can go right through enemies
HitActor = Other;
X = Normal(Velocity);
SetLocation(HitLocation + (X * (Other.CollisionHeight*2*X.Z + Other.CollisionRadius*2*(1-X.Z)) * 1.2));
   if ( EffectIsRelevant(Location,false) && PenetrateManager != None)
PenetrateManager.static.StartSpawn(HitLocation, Other.Location-HitLocation, Other.SurfaceType, Owner, 4/*HF_NoDecals*/);
}
else if (Role == ROLE_Authority)
{
// Spawn projectile death effects and try radius damage

HitActor = Other;
Explode(HitLocation, vect(0,0,1));
}
}

simulated singular function HitWall(vector HitNormal, actor Wall)
{
local PlayerController PC;

if ( Role == ROLE_Authority )
{
if ( !Wall.bStatic && (!Wall.bWorldGeometry || Wall.bCanBeDamaged) )
{
if ( Instigator == None || Instigator.Controller == None )
Wall.SetDelayedDamageInstigatorController( InstigatorController );
Wall.TakeDamage( Damage, instigator, Location, MomentumTransfer * Normal(Velocity), MyDamageType);
if (DamageRadius > 0 && Vehicle(Wall) != None && Vehicle(Wall).Health > 0)
Vehicle(Wall).DriverRadiusDamage(Damage, DamageRadius, InstigatorController, MyDamageType, MomentumTransfer, Location);
HurtWall = Wall;
}
MakeNoise(1.0);
}
Explode(Location + ExploWallOut * HitNormal, HitNormal);
if ( (ExplosionDecal != None) && (Level.NetMode != NM_DedicatedServer)  )
{
if ( ExplosionDecal.Default.CullDistance != 0 )
{
PC = Level.GetLocalPlayerController();
if ( !PC.BeyondViewDistance(Location, ExplosionDecal.Default.CullDistance) )
Spawn(ExplosionDecal,self,,Location, rotator(-HitNormal));
else if ( (Instigator != None) && (PC == Instigator.Controller) && !PC.BeyondViewDistance(Location, 2*ExplosionDecal.Default.CullDistance) )
Spawn(ExplosionDecal,self,,Location, rotator(-HitNormal));
}
else
Spawn(ExplosionDecal,self,,Location, rotator(-HitNormal));
}
HurtWall = None;
}

simulated function DoDamage(Actor Other, vector HitLocation)
{
local class<DamageType> DT;
local float Dmg;
    local Vector ClosestLocation, BoneTestLocation, temp;

if ( Instigator == None || Instigator.Controller == None )
Other.SetDelayedDamageInstigatorController( InstigatorController );

if (xPawn(Other) != None)
{
//Find a point on the victim's Z axis at the same height as the HitLocation.
ClosestLocation = Other.Location;
ClosestLocation.Z += (HitLocation - Other.Location).Z;

//Extend the hit along the projectile's Velocity to a point where it is closest to the victim's Z axis.
temp = Normal(Velocity);
temp *= VSize(ClosestLocation - HitLocation);
BoneTestLocation = temp;
BoneTestLocation *= normal(ClosestLocation - HitLocation) dot normal(temp);
BoneTestLocation += HitLocation;

class'BallisticDamageType'.static.GenericHurt (GetDamageVictim(Other, BoneTestLocation, Normal(Velocity), Dmg, DT), Dmg, Instigator, HitLocation, MomentumTransfer * Normal(Velocity), DT);
}
else class'BallisticDamageType'.static.GenericHurt (GetDamageVictim(Other, HitLocation, Normal(Velocity), Dmg, DT), Dmg, Instigator, HitLocation, MomentumTransfer * Normal(Velocity), DT);
}

simulated function bool CanPenetrate(Actor Other)
{
if (!bPenetrate || Other == None || Other.bWorldGeometry || Mover(Other) != None || Vehicle(Other) != None || DestroyableObjective(Other) != None)
return false;
return true;
}
simulated function Actor GetDamageVictim (Actor Other, vector HitLocation, vector Dir, out float Dmg, optional out class<DamageType> DT)
{
local string Bone;
local float BoneDist;
local Vector HitLocationMatchZ;
local Pawn DriverPawn;

Dmg = Damage;
DT = MyDamageType;

if (!bUsePositionalDamage || Monster(Other) != None)
return Other;

if (Pawn(Other) != None)
{
if (Vehicle(Other) != None)
{
// Try to relieve driver of his head...
DriverPawn = Vehicle(Other).CheckForHeadShot(HitLocation, Dir, 1.0);
if (DriverPawn != None)
{
Other = DriverPawn;
Dmg = DamageHead;

if (DamageTypeHead != None)
DT = DamageTypeHead;
}
}

else
{
HitLocationMatchZ = HitLocation;
HitLocationMatchZ.Z = Other.Location.Z;

// Check for head shot
Bone = string(Other.GetClosestBone(HitLocation, Dir, BoneDist, 'head', 10));
if (InStr(Bone, "head") > -1)

{
if (class'BallisticWeapon'.default.bUseModifiers)
Dmg *= DamageModHead;
else Dmg = DamageHead;

if (DamageTypeHead != None)
DT = DamageTypeHead;
}

// Limb shots
else if (HitLocation.Z < Other.Location.Z - (Other.CollisionHeight/6) || VSize(HitLocationMatchZ - Other.Location) > 22) //accounting for groin region here
{
if (class'BallisticWeapon'.default.bUseModifiers)
Dmg *= DamageModLimb;
else if(class'BallisticWeapon'.default.bEvenBodyDamage)
{
Dmg = Damage;
}
else Dmg = DamageLimb;

if (DamageTypeLimb != None)
DT = DamageTypeLimb;
}
}
}

return Other;
}

// Special HurtRadius function. This will hurt everyone except the chosen victim.
// Useful if you want to spare a directly hit enemy from the radius damage
function TargetedHurtRadius( float DamageAmount, float DamageRadius, class<DamageType> DamageType, float Momentum, vector HitLocation, Optional actor Victim )
{
local actor Victims;
local float damageScale, DmgRadiusScale, dist;
local vector dir;

if( bHurtEntry )
return;

bHurtEntry = true;
foreach CollidingActors( class 'Actor', Victims, DamageRadius, HitLocation )
{
// don't let blast damage affect fluid - VisibleCollisingActors doesn't really work for them - jag
if( (Victims != self) && (Victims.Role == ROLE_Authority) && (!Victims.IsA('FluidSurfaceInfo')) && Victims != Victim && Victims != HurtWall)
{
//Cover penetration code for explosives.
if (!FastTrace(Victims.Location, Location))
{
if (!bCoverPenetrator)
continue;
else DmgRadiusScale = (DamageRadius - GetCoverReductionFor(Victims.Location)) / DamageRadius;

if (DamageRadius * DmgRadiusScale < 16)
continue;
}
else DmgRadiusScale = 1;

dir = Victims.Location;
if (Victims.Location.Z > HitLocation.Z)
dir.Z = FMax(HitLocation.Z, dir.Z - Victims.CollisionHeight);
else dir.Z = FMin(HitLocation.Z, dir.Z + Victims.CollisionHeight);
dir -= HitLocation;
dist = FMax(1,VSize(dir));
if (bCoverPenetrator && DmgRadiusScale < 1 && VSize(dir) > DamageRadius * DmgRadiusScale)
continue;
dir = dir/dist;
damageScale = 1 - FMax(0,(dist - Victims.CollisionRadius)/ (DamageRadius * DmgRadiusScale));
if ( Instigator == None || Instigator.Controller == None )
Victims.SetDelayedDamageInstigatorController( InstigatorController );
class'BallisticDamageType'.static.GenericHurt
(
Victims,
Square(damageScale) * DamageAmount,
Instigator,
Victims.Location - 0.5 * (Victims.CollisionHeight + Victims.CollisionRadius) * dir,
(damageScale * Momentum * dir),
DamageType
);
}
}
bHurtEntry = false;
}

function float GetCoverReductionFor(vector TargetLoc)
{
local Vector HitLocation, HitLocationTwo, HitNormal;
local Material HitMat;
local float MatScale, Dist;
local byte bHard;

Trace(HitLocation, HitNormal, TargetLoc, Location, false, , HitMat);

Trace(HitLocationTwo, HitNormal, Location, TargetLoc, false);

if (HitMat != None)
MatScale = SurfaceScale(int(HitMat.SurfaceType), bHard);
else MatScale = 1;

Dist = VSize(HitLocation - HitLocationTwo);

if (bHard == 0)
return Dist / MatScale;
else if (Dist / MatScale > DamageRadius)
return 0;
return 1;
}

defaultproperties
{
     bRandomStartRotaion=True
     bTearOnExplode=True
     NetTrappedDelay=0.150000
     DamageModHead=1.500000
     DamageModLimb=1.000000
     ShakeRadius=-1.000000
     bWarnEnemy=True
     MotionBlurRadius=-1.000000
     MotionBlurFactor=4.000000
     MotionBlurTime=5.000000
     ShakeRotMag=(X=256.000000,Y=256.000000,Z=256.000000)
     ShakeRotRate=(X=2500.000000,Y=2500.000000,Z=2500.000000)
     ShakeRotTime=6.000000
     ShakeOffsetMag=(X=10.000000,Y=10.000000,Z=20.000000)
     ShakeOffsetRate=(X=200.000000,Y=200.000000,Z=200.000000)
     ShakeOffsetTime=6.000000
     MaxSpeed=0.000000
     DamageRadius=0.000000
     DrawType=DT_StaticMesh
}

class DT_AP extends BallisticDamageType;

defaultproperties
{
FemaleSuicide="%o minigunned her feet into tatters."
MaleSuicide="%o minigunned his feet into tatters."
bFastInstantHit=True
KDamageImpulse=150000.000000
VehicleDamageScaling=1.000000
}

class BallisticDamageType extends WeaponDamageType config(BallisticProMainOff);

var() localized Array<string> DeathStrings; // Multiple deathstrings may be interesting...
var() localized Array<string> FemaleSuicides, MaleSuicides; // Multiple suicide messages
var() localized string SimpleKillString, SimpleSuicideString;
var() localized string HipString, AimedString;
var() localized string His, Her, Himself, Herself, Him, MHer, He, She;

var() float EffectChance; // Chance of blood effect appearing
var() class<BloodManager> BloodManager; // BloodManager loaded from BloodManagerName
var() string BloodManagerName; // BloodManager to use for this damagetype
var   bool bCantLoadBlood; // No able to load BloodManager. So we know not to keep trying...

var int FlashThreshold;
var vector FlashV;
var float FlashF;

var() bool bCanBeBlocked; // This damage(eg. sword slash) can be blocked with a shield, sword or whatever...
var() int ShieldDamage; // Damage this can do to shields that block it (for future mod purposses, used by JunkWar)
var() bool bDetonatesBombs; // This damage can detonate bombs, mines, etc...
var() bool bIgniteFires; // This damage can ignite flammable things and cause fires.
var() byte ArmorHitType; // Tells BArmor what effects to use (Bullet, Misc or None)
var() bool bSnipingDamage;   // Ballistic Freon - extend camp check longer than normal
var() bool bPowerPush; // 3SPN: Attacks of this damagetype impart a lot of momentum and are commonly used for abusive purposes
var() bool bHeaddie; // Is a headshot damagetype
var() bool bIgnoredOnLifts; //If used against a player on a lift, or exiting a lift, this damagetype will be ignored completely
var() float InvasionDamageScaling; // Scale the damage by this in Invasion (because Invasion requires different balance to PvP)
var string DamageIdent; // The stats slot this damagetype fits into
var() bool bDisplaceAim; // This damagetype forcibly displaces the weapon if it hits
var() int AimDisplacementDamageThreshold;
var() float AimDisplacementDuration;

var globalconfig bool bSimpleDeathMessages; //Simplify DMs

var() string DamageDescription; // Words that describe this damagetype. e.g. ",Poison,Melee,Bite," or ",Electro,Lightning,"
// Makes it easier for systems to identify the damage and work accordingly...
// Always seperate the keywords with commas like in examples!

/* This will be expanded upon later and implemented as the system develops and demand rises
Some Standard Damage Description Words:
,Bullet, Done by ballistic bullet weapon, e.g. Pistol, Machinegun, Rifle, etc
,Shell, Done by shotgun shell, e.g. Shotgun shell...
,Flame, Done by fire, e.g. Flame thrower, Incendiary grenade, etc
,Explode, Done by explosion, e.g. Bomb, rocket, grenade
,Blunt, Done by blunt weapon, e.g. Baseball bat, Shotgun butt, South African bread
,Hack, Done by heavy hack style weapon, e.g. Axe
,Stab, Done by stab weapon, e.g. Knife, harpoon, spear, bayonette
,Slash, Done by swung blade weapon, e.g. Knife, Sword, Scythe
,Plasma,
,Laser, Laser type things
,Electro, Electical type damage like lightning
,RoadKill, Run down by a vehicle
,Gas, Done by poison gas, e.g. Deadly green gas, Deadly yellow gas, other deadly gasses...
,Liquid, Submerged in death
,Poison, Vic was poisoned by a damage that continued hurting after the hit
,Ice, Damage is cold and icy by nature. e.g. Freeze gun
,GearSafe, Doesn't tear into a victim or cut through armor and gas tanks, basically doesn't harm the gear, just the guy inside... Likely used with: Poison, Gas, Liquid
,Hazard, Done by hazardous weapon, ie. one that can easily damage the user. e.g. Explosives, grenades, fire, etc
,NonSniper, Not possible for this damage to be the result of marksmanship. eg. Traps, Mines, Bombs, Explosives
*/

var() class<BCImpactManager> ImpactManager; // Impact effects associated with this damage

// New gore system vars
var() bool bMultiSever; // Don't just sever the hitbone, try the other bones too
var() bool bOnlySeverLimbs; // Do not sever spine or pelvis, no matter how much damage
var() bool bSeverPreventsBlood; // No blood hit effects if the bone was severed
var() bool bNoSeverStumps; // Don't spawn attached stumps

// Motion blur caused by this damage
var() float MinMotionBlurDamage; // Damage that must be done to start causing motion blur
var() float MotionBlurDamageRange; // Damage amount beyond MinMotionBlurDamage at which max blur is acheived
var() float MotionBlurFactor; // Amount of blur to apply. 0 None, 1 Full, >1 Stays full longer  (scaled depending on damage)
var() float MotionBlurTime; // How long blur is applied (also scaled depending on damage... obviously)
var() bool bUseMotionBlur; // use motion blur effects for this DT

// This lets you put some his/her type words in the death messages
// %ke: killer he/she
// %ve: vicitm he/she
// %km: killer him/her
// %vm: vicitm him/her
// %kh: killer his/her
// %vh: vicitm his/her
// %ks: killer himself/herself
// %vs: vicitm himself/herself
static function string Detag (string s, PlayerReplicationInfo Victim, PlayerReplicationInfo Killer)
{
local string kh, vh, vs, ks, km, vm, ve, ke;

if (Victim!=None && Victim.bIsFemale) {
vh = default.Her;
vs = default.Herself;
vm = default.MHer;
ve = default.She; }
else {
vh = default.His;
vs = default.Himself;
vm = default.Him;
ve = default.He; }
if (Killer != None && Killer.bIsFemale) {
kh = default.Her;
ks = default.Herself;
km = default.MHer;
ke = default.She; }
else {
kh = default.His;
ks = default.Himself;
km = default.Him;
ke = default.He; }

SwitchText(s, "%ke", ke);
SwitchText(s, "%ve", ve);
SwitchText(s, "%km", km);
SwitchText(s, "%vm", vm);
SwitchText(s, "%kh", kh);
SwitchText(s, "%vh", vh);
SwitchText(s, "%ks", ks);
SwitchText(s, "%vs", vs);
return s;
}
static function SwitchText(out string Text, string Replace, string With)
{
local int i;
local string Input;

Input = Text;
Text = "";
i = InStr(Input, Replace);
while(i != -1)
{
Text = Text $ Left(Input, i) $ With;
Input = Mid(Input, i + Len(Replace));
i = InStr(Input, Replace);
}
Text = Text $ Input;
}

static function bool IsAimed(PlayerController PC)
{
if (PC.Pawn != None && BallisticWeapon(PC.Pawn.Weapon) != None && BallisticWeapon(PC.Pawn.Weapon).SightingState != SS_None)
return true;
return false;
}

// Random messages
static function string DeathMessage(PlayerReplicationInfo Killer, PlayerReplicationInfo Victim)
{
local string s, t;

if (default.bSimpleDeathMessages)
{
if (default.WeaponClass == None)
s = "%k ["$GetItemName(String(default.Class))$"] %o";
else
{
if(default.SimpleKillString == "")
t = default.WeaponClass.default.ItemName;
else t = default.SimpleKillString;
if(default.HipString != "")
t @= default.HipString;
if (default.DamageIdent == "Melee" && default.WeaponClass.default.InventoryGroup != 1)
t @= "Melee";
if (default.bHeaddie)
t @= "Headshot";
s = "%k ["$t$"] %o";
}
}

else if (default.DeathStrings.Length > 0)
s = default.DeathStrings[Rand(default.DeathStrings.Length)];
else
s = default.DeathString;
return static.Detag(s, Victim, Killer);
}

// Scoped death message (only for Simple DMs and with gametype support)
static function string ScopedDeathMessage(PlayerReplicationInfo Killer, PlayerReplicationInfo Victim)
{
local string s, t;

if (default.WeaponClass == None)
s = "%k ["$GetItemName(String(default.Class))$"] %o";
else
{
if(default.SimpleKillString == "")
t = default.WeaponClass.default.ItemName;
else t = default.SimpleKillString;
if (default.DamageIdent == "Melee" && default.WeaponClass.default.InventoryGroup != 1)
t @= "Melee";
t @= default.AimedString;
if (default.bHeaddie)
t @= "Headshot";
s = "%k ["$t$"] %o";
}

return static.Detag(s, Victim, Killer);
}

static function string SuicideMessage(PlayerReplicationInfo Victim)
{
if (default.bSimpleDeathMessages)
{
if (default.WeaponClass == None)
return "["$default.Class$"] %o";
if(default.SimpleKillString == "")
return "["$default.WeaponClass.default.ItemName$"] %o";
return "["$default.SimpleKillString$"] %o ";
}
if (Victim.bIsFemale && default.FemaleSuicides.Length < 1)
return default.FemaleSuicide;
if (default.MaleSuicides.Length < 1)
return default.MaleSuicide;
if (Victim.bIsFemale)
return default.FemaleSuicides[Rand(default.FemaleSuicides.Length)];
return default.MaleSuicides[Rand(default.MaleSuicides.Length)];
}

// Is keyword in description: Keep the commas in the keyword!  e.g. ,Fire, ,Gas, ,Bullet,
static function bool IsDamage(string TypeString)
{
return InStr(default.DamageDescription, TypeString) >= 0;
}

// Call this to do damage to something. This lets the damagetype modify the things if it needs to
static function Hurt (Actor Victim, float Damage, Pawn Instigator, vector HitLocation, vector Momentum, class<DamageType> DT)
{
Victim.TakeDamage(Damage, Instigator, HitLocation, Momentum, DT);
}
// Compatability for Hurt(), Call this with the DamageType if it might not be a BallisticDamageType
// Use like this: class'BallisticDamageType'.static.GenericHurt (..., QuestionableDamagetype);
static function GenericHurt (Actor Victim, float Damage, Pawn Instigator, vector HitLocation, vector Momentum, class<DamageType> DT)
{
if (class<BallisticDamageType>(DT) != None)
class<BallisticDamageType>(DT).static.Hurt (Victim, Damage, Instigator, HitLocation, Momentum, DT);
else
Victim.TakeDamage(Damage, Instigator, HitLocation, Momentum, DT);
}

// Spawn some blood effects
static function DoBloodEffects( vector HitLocation, float Damage, vector Momentum, Pawn Victim, bool bLowDetail )
{
if (Monster(Victim) == None && !Victim.PhysicsVolume.bWaterVolume && !default.bCantLoadBlood && GetBloodManager() != None)
GetBloodManager().static.StartSpawnBlood(HitLocation + Normal(momentum)*Victim.CollisionRadius*1.5, Momentum, Victim);
}
// Spawn some blood effects
static function class<BloodManager> GetBloodManager ()
{
if (default.BloodManager == None)
{
default.BloodManager = class<BloodManager>(DynamicLoadObject(default.BloodManagerName,class'class',true));
if (default.BloodManager == None)
default.bCantLoadBlood = true;
}
return default.BloodManager;
}

// Plays a sound when this damage is done to pawns
// This is a hook for damage specific blood effects
static function class<Effects> GetPawnDamageEffect( vector HitLocation, float Damage, vector Momentum, Pawn Victim, bool bLowDetail )
{
if (xPawn(Victim) != None)
{
if (default.PawnDamageSounds.Length > 0)
Victim.PlaySound(default.PawnDamageSounds[Rand(default.PawnDamageSounds.Length)],,default.TransientSoundVolume,,default.TransientSoundRadius);
if (default.EffectChance > 0 && default.EffectChance > FRand())
DoBloodEffects(HitLocation, Damage, Momentum, Victim, bLowDetail);
if (Damage >= default.FlashThreshold)
{
if (PlayerController(Victim.Controller) != None)
PlayerController(Victim.Controller).ClientFlash(default.FlashF, default.FlashV);
}
}
return super.GetPawnDamageEffect(HitLocation, Damage, Momentum, Victim, bLowDetail);
}

// Apply motion blur
static function LocalHitEffects (Pawn Victim, name HitBone, vector HitLocation, vector HitRay, int Damage)
{
local float ScaleFactor;

if (default.bUseMotionBlur && Victim.level.NetMode != NM_DedicatedServer && Victim.level.GetLocalPlayerController().ViewTarget == Victim /*Victim.IsLocallyControlled() PlayerController(Victim.Controller) != None*/ && Damage > default.MinMotionBlurDamage)
{
ScaleFactor = FMin(1.0, (Damage-default.MinMotionBlurDamage)/default.MotionBlurDamageRange);
class'BC_MotionBlurActor'.static.DoMotionBlur(PlayerController(Victim.Controller), default.MotionBlurFactor * ScaleFactor, default.MotionBlurTime * ScaleFactor);
}
}

// Pawn gives damage type a chance to modify hit properties. Called from PlayHit, so changes affect only effects, TakeDamage will be done already.
static function ModifyHit (Pawn Victim, out float Damage, vector Momentum, out vector HitLocation, out vector HitRay, out name HitBone);

// Return true to decide a sever from here instead of using pawn's default code. Set bCanSever to desired result.
static function bool OverrideCanSever(Pawn Pawn, name Bone, int Damage, vector HitLoc, vector HitRay, bool bDirectHit, out byte bCanSever);

// Spawn some blood effects
static function bool DoBloodHit (Pawn Victim, name Bone, vector HitLoc, vector HitRay, int Damage)
{
if (default.bCantLoadBlood || GetBloodManager() == None)
return false;
GetBloodManager().static.DoBloodHit(Victim, Bone, HitLoc, HitRay, Damage);
return true;
}
// Spawn sever effects
static function bool DoSeverEffect (Pawn Victim, name Bone, vector HitRay, int Damage)
{
if (default.bCantLoadBlood || GetBloodManager() == None)
return false;
GetBloodManager().static.DoSeverEffects(Victim, Bone, HitRay, default.GibPerterbation, Damage);
return true;
}
// Spawn sever stump
static function bool DoSeverStump (Pawn Victim, name Bone, vector HitRay, int Damage)
{
if (default.bCantLoadBlood || GetBloodManager() == None)
return false;
if (default.bNoSeverStumps)
return true;
GetBloodManager().static.DoSeverStump(Victim, Bone, HitRay, Damage);
return true;
}

defaultproperties
{
AimedString="Aimed"
His="his"
Her="her"
Himself="himself"
Herself="herself"
Him="him"
MHer="her"
He="he"
She="she"
FlashThreshold=200
bDetonatesBombs=True
ArmorHitType=255
InvasionDamageScaling=0.100000
DamageIdent="Unknown"
AimDisplacementDuration=0.600000
MinMotionBlurDamage=10.000000
MotionBlurDamageRange=80.000000
MotionBlurFactor=4.000000
MotionBlurTime=2.000000
bDetonatesGoop=True
bKUseTearOffMomentum=True
bRagdollBullet=True
bExtraMomentumZ=False
bDirectDamage=False
KDamageImpulse=20000.000000
TransientSoundVolume=1.000000
TransientSoundRadius=64.000000
}